En esta entrada os voy a explicar un truco bastante útil para los que sois swichers, es decir, usuarios que han trabajado muchos años en Windows y os habéis pasado al mundo Mac OS. Como suelen decir, venís del lado oscuro.

Personalmente considero que no debemos ser fanáticos de nada en la vida, los fanatismos nos cierran la mente y nos nublan otras posibilidades. En este caso, aplicado a los sistemas, considero que no existe un SO perfecto, y siempre las cosas son mejorables. Es cierto que algunos sistemas pueden ser mejor que otros, pero no implica que tengamos que cerrarnos e incorporar nuevas ideas. Valorar las que otros tienen.

En concreto yo suelo trabajar con diversos sistemas, y una cosa que me parece bastante interesante de Windows es que puedes crear archivos de texto desde cualquier sitio, simplemente con el segundo botón del ratón. Se que para muchos de vosotros a lo mejor no es necesario, pero cuando trabajo en Mac, me gustaría disponer de esa pequeña característica, realmente la hecho en falta.

Investigando en la red, encontré una aplicación llamada NewTextFileHere, que hace precisamente lo que os digo, pero le he encontrado «tres  inconvenientes».

Agradeciendo el creador la voluntad y esfuerzo invertido en la comunidad, me encuentro con el problema que no funciona sobre la versión de Mac que estoy trabajando que es «El Capitán«, lo segundo que no he sido capaz de crear las carpetas con teclas asociadas, y lo tercero es que no se bien que hace internamente al ser una App compilada.

Por otro lado me gustaría poder desarrollar e indagar cómo poder hacerlo nosotros mismos, así aprendemos un poco más sobre las interioridades del sistema.

Por eso, os voy a dejar un script que funciona, y os voy a explicar al detalle como se ha realizado y los pasos necesarios para lograrlo. Será una utilidad única …

Manos a la obra …

Si bien es cierto, podemos crear archivos directamente desde la terminal llamando al programa textedit de la siguiente forma:

En la carpeta donde deseemos lanzamos un:

touch mi_fichero.txt

abrimos el fichero creado con:

open -a TextEdit mi_fichero.txt

Bueno, esto es un mecanismo-a, pero ya vemos que es lento-a. 😉

Otra es lanzar el editor de texto, y desde el propio editor guardar como …, no es lo que quiero exactamente.

Lo que vamos a realizar es lo siguiente:

Vamos a pulsar la tecla cmd y la barra espaciadora, y ejecutamos:

Automator

Mediante  Automator puedes automatizar muchas de las tareas que realizas con tu ordenador. Crear e imprimir un directorio con los contactos de tu Agenda. Buscar y añadir imágenes desde tus sitios web favoritos a iPhoto. Imprimir documentos en tu iPad. Renombrar innumerables archivos en el Finder en un solo paso. Incluso realizar copias de seguridad programadas de datos importantes.  Automator hace en cuestión de segundos y minutos lo que te llevaría horas hacer a mano.

Una vez abierto automator haremos lo siguiente:

Creamos un servicio.

Ahora es importante indicar que el servicio no recibe datos de entrada, y se ejecuta en Finder.app

Selecciona «Ejecutar AppleScript«, pega el código inferior, borrando el que ya existe.

Si pulsas al botón Play, verás que esto ya funciona, puesto que ha creado un archivo en el escritorio de tipo txt, llamado sin titulo.

set file_name to "sin-titulo"
set file_ext to ".txt"
set is_desktop to false

--  obtiene la ruta de la carpeta y si estamos en el escritorio (no se abre la carpeta)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- No abre la carpeta windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- Obtiene el nombre del fichero (no lo sobreescribe si ya existe)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- Crea y selecciona el nuevo fichero
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- Presiona enter para renombrar el fichero
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

Una vez realizado esto, vamos a grabar el servicio, en el menu de Automator, Archivo guardar.

Le daremos un nombre le llamaremos, nuevo fichero de texto.

Realmente lo que se guarda es un servicio, que puedes ya usar desde el finder, en el menu,

Finder, Servicios, General, veras una nueva entrada llamada «Nuevo Fichero de texto».

Ahora para asignarle la combinación de teclas que deseemos, nos vamos al menu, preferencias del sistema->teclado-> Funciones rápidas-> Servicios.

En la imagen inferior verás como he asignado la tecla Control N, para crear un archivo de texto desde el sitio donde desee.

Realmente un servicio es un archivo de texto ubicado en la siguiente carpeta (ver ruta).

Si quieres borrar el servicio, simplemente borra este archivo.

Ta Chan!!!, ya tienes la posibilidad de crear archivos de texto desde cualquier sitio en tu MacOS.

Además esta utilidad funciona en la última versión de tu Mac. (Capitan).

Esto es todo. Ahora vas y lo cascas. 🙂